Ссылка на видео:
Скачайте изображение из интернета с текстурой воды и добавьте её в атлас:
Создайте скрипт для будущего игрового объекта:
Перейдите в строенную папку проекта builtins, а затем в папку materials:
Скопируйте два этих файла:
В какую-нибудь папку вашего проекта:
В main.collection создайте игровой объект с такими компонентами:
Измените настройки компоненту sprite, на ваши соответствующие атлас и материал:
Добавь в ваш новый materials путь к вашему фрагментному шейдеру:
В ваш фрагментный шейдер добавь (у меня water.fp):
Развернуть код:
varying mediump vec2 var_texcoord0;
uniform lowp sampler2D texture_sampler;
uniform lowp vec4 tint;
uniform lowp vec4 u_time;
vec2 random2D(vec2 p) {
return fract(sin(vec2(dot(p, vec2(127.1, 311.7)),
dot(p, vec2(269.5, 183.3)))) * 43758.5453);
}
vec4 permute(vec4 x) {
return mod(((x * 34.0) + 1.0) * x, 289.0);
}
vec4 taylorInvSqrt(vec4 r) {
return 1.79284291400159 - 0.85373472095314 * r;
}
float snoise(vec3 v) {
const vec2 C = vec2(1.0 / 6.0, 1.0 / 3.0);
const vec4 D = vec4(0.0, 0.5, 1.0, 2.0);
vec3 i = floor(v + dot(v, C.yyy));
vec3 x0 = v - i + dot(i, C.xxx);
vec3 g = step(x0.yzx, x0.xyz);
vec3 l = 1.0 - g;
vec3 i1 = min(g.xyz, l.zxy);
vec3 i2 = max(g.xyz, l.zxy);
vec3 x1 = x0 - i1 + 1.0 * C.xxx;
vec3 x2 = x0 - i2 + 2.0 * C.xxx;
vec3 x3 = x0 - 1.0 + 3.0 * C.xxx;
i = mod(i, 289.0);
vec4 p = permute(permute(permute(
i.z + vec4(0.0, i1.z, i2.z, 1.0))
+ i.y + vec4(0.0, i1.y, i2.y, 1.0))
+ i.x + vec4(0.0, i1.x, i2.x, 1.0));
float n_ = 1.0 / 7.0;
vec3 ns = n_ * D.wyz - D.xzx;
vec4 j = p - 49.0 * floor(p * ns.z * ns.z);
vec4 x_ = floor(j * ns.z);
vec4 y_ = floor(j - 7.0 * x_);
vec4 x = x_ * ns.x + ns.yyyy;
vec4 y = y_ * ns.x + ns.yyyy;
vec4 h = 1.0 - abs(x) - abs(y);
vec4 b0 = vec4(x.xy, y.xy);
vec4 b1 = vec4(x.zw, y.zw);
vec4 s0 = floor(b0) * 2.0 + 1.0;
vec4 s1 = floor(b1) * 2.0 + 1.0;
vec4 sh = -step(h, vec4(0.0));
vec4 a0 = b0.xzyw + s0.xzyw * sh.xxyy;
vec4 a1 = b1.xzyw + s1.xzyw * sh.zzww;
vec3 p0 = vec3(a0.xy, h.x);
vec3 p1 = vec3(a0.zw, h.y);
vec3 p2 = vec3(a1.xy, h.z);
vec3 p3 = vec3(a1.zw, h.w);
vec4 norm = taylorInvSqrt(vec4(dot(p0, p0), dot(p1, p1),
dot(p2, p2), dot(p3, p3)));
p0 *= norm.x;
p1 *= norm.y;
p2 *= norm.z;
p3 *= norm.w;
vec4 m = max(0.6 - vec4(dot(x0, x0), dot(x1, x1),
dot(x2, x2), dot(x3, x3)), 0.0);
m = m * m;
return 42.0 * dot(m * m, vec4(dot(p0, x0), dot(p1, x1),
dot(p2, x2), dot(p3, x3)));
}
vec3 voronoiDiagram(vec2 position, float time) {
vec2 cellIndex = floor(position);
vec2 cellOffset = fract(position);
vec2 minGrid, minOffset;
float minDistance = 8.0;
for (int j = -1; j <= 1; j++) {
for (int i = -1; i <= 1; i++) {
vec2 grid = vec2(float(i), float(j));
vec2 offset = random2D(cellIndex + grid);
offset = 0.5 + 0.5 * sin(time + 6.2831 * offset);
vec2 relativePos = grid + offset - cellOffset;
float distance = dot(relativePos, relativePos);
if (distance < minDistance) {
minDistance = distance;
minOffset = relativePos;
minGrid = grid;
}
}
}
minDistance = 8.0;
for (int j = -2; j <= 2; j++) {
for (int i = -2; i <= 2; i++) {
vec2 grid = minGrid + vec2(float(i), float(j));
vec2 offset = random2D(cellIndex + grid);
offset = 0.5 + 0.5 * sin(time + 6.2831 * offset);
vec2 relativePos = grid + offset - cellOffset;
minDistance = min(minDistance, dot(minOffset + relativePos,
normalize(relativePos - minOffset)));
}
}
return vec3(minDistance, minOffset);
}
float smin(float a, float b, float k) {
float res = exp2(-k * a) + exp2(-k * b);
return -log2(res) / k;
}
void main()
{
float time = u_time.x;
vec2 uv = var_texcoord0;
uv *= vec2(2.0, 5.0);
uv.y += time * 0.3;
uv.y += sin(time + uv.y) * 0.3;
uv.y += sin(time + uv.x) * 0.3;
uv.x += sin(time) * 0.1;
float wiggle = 0.15 + 0.15 * snoise(vec3(uv * vec2(1.0, 3.0), time * 0.3));
uv += wiggle * snoise(vec3(uv, -time * 0.25));
vec3 voronoi = voronoiDiagram(uv, time * 0.1);
vec3 col = vec3(0.07, 0.7, 1.0);
float thickness = 0.15;
thickness += snoise(vec3(uv * 0.5, time * 0.1)) * 0.18;
thickness += snoise(vec3(uv * 3.0, -time * 0.5)) * 0.10;
thickness += snoise(vec3(uv * 50.0, -time * 2.0)) * 0.02;
float border = smoothstep(voronoi.x, voronoi.x + 0.35, thickness);
col += border * vec3(0.3, 0.2, 0.0);
float middle = 0.3 * smin(0.1, snoise(vec3(uv * 0.5, time * 0.25)) + 1.0, 0.95);
col.g += middle;
lowp vec4 sprite_color = texture(texture_sampler, var_texcoord0);
vec3 final_color = mix(sprite_color.rgb, col, 0.6);
lowp vec4 tint_pm = vec4(tint.xyz * tint.w, tint.w);
gl_FragColor = vec4(final_color, sprite_color.a) * tint_pm;
}
В ваш script (у меня water.script) добавь такой блок кода:
Развернуть код:
go.property("speed", 1.0)
function init(self)
self.time = 0
end
function update(self, dt)
self.time = self.time + dt * self.speed
sprite.set_constant("#sprite", "u_time", vmath.vector4(self.time, 0, 0, 0))
end